'------------------------------------------
	'   SCRIPT PARA EVITAR QUE SE LLENE EL    -
	'   DISCO DURO, BORRANDO CARPETAS CREADAS -
	'   EN LOS RECORDS DE LA CENTRALITA.      -
	'   FICHERO CREADO EL 20/08/2008          -
	'   AUTOR: JUAN GREGORIO CARVAJAL         -
	'	La licencia de uso es libre y se puede-
	'   Modificar a tu libre antojo, y gusto  -
	'   Si lo modificas y lo mejoras mandame  -
	'   una copia a mi						  -
	'   correo carvajal@transunionmallorca.com- 
	'------------------------------------------
	
	Dim intGbMin
	Dim strDirectoryName
	Dim strHddComprobar
	
	Wscript.Echo Wscript.Version			'Version de WScript

	
	' Variables modificables del script:
	'---------------------------------------------------------------------------

	intGbMin = 10							'Cantidad en número entero 
											'de GB mínimos para el 
											'disco duro a comprobar.

	strHddComprobar = "c:\"					'Disco duro del que se va a
											'verificar el espacio libre
	
	
	strDirectoryName = "c:\sutil\records"	'Directorio del script 
											'de donde se van a borrar 
											'las carpetas que contiene

	'-------------------------------------------------------------------------
	Wscript.Echo "Minimo de GB de HDD: " & intGbMin
	Wscript.Echo "Disco duro a comprobar: " & strHddComprobar
	Wscript.Echo "Directorio del que borrar las carpetas: " & strDirectoryName
    

	Dim intCon		'Varibale contadora
		intCon = 0

	Dim fso			'Variable para crear el FileSystemObject
	Set fso = CreateObject("Scripting.FileSystemObject")
	
	Dim varMainDrive
	
	Dim varGbHDD	'Cantidad de Gb que tiene el HDD
		varGbHdd = 0

	Dim strFolder	'Carpeta que se va a borrar si la comprobación es correcta.
		strFolder = ""
	Dim strDate		'Variable que contiene la fecha de comprobación.
		strDate = Date
	
	'Variables para recorrer todas las carpetas
	'Del directorio donde se buscan las carpetas que
	'van a ser borradas.
	Dim varDirFolder, varFolderCollection, varFolder
	
	Do 
		
		intCon = intCon + 1		'Variable para impedir un bucle infinito.
		strDate = Date

		Set varMainDrive = fso.GetDrive(strHddComprobar)

		varGbHDD = varMainDrive.FreeSpace				'Variable que contiene el
		varGbHDD = int(((varGbHDD/1024)/1024)/1024)		'Espacio de HDD en GB.
		Wscript.Echo "Cantidad de espacio libre en HDD actual: " & varGbHDD & " Gb."

		Set varMainDrive = Nothing

		'Si el valor es inferior al minimo borrar la carpeta mas vieja.
		If varGbHDD < intGbMin Then
			Wscript.Echo "Buscando la posible carpeta a borrar."

			Set varDirFolder = fso.GetFolder(strDirectoryName)
			Set varFolderCollection = varDirFolder.SubFolders
			
			For Each varFolder In varFolderCollection

				If CDate(varFolder.DateCreated) < CDate(strDate) Then
					strFolder = varFolder.Name
					strDate = varFolder.DateCreated
				End If

			Next

			Set varFolderCollection = Nothing
			Set varDirFolder = Nothing
			
			'Si se ha encontrado la carpeta a borrar
			'Iniciar el proceso de borrado
			If strFolder <> "" Then

				Wscript.Echo "Borrar la carpeta: " & strDirectoryName & "\" & strFolder
				fso.DeleteFolder strDirectoryName & "\" & strFolder
				
			End If

		End If
		
		'Condicion para salir si el bucel se repite
		'mas de 4 veces
		If intCon > 4 Then
			intCon = 0
			Exit Do
		End If
		
	Loop While varGbHDD < intGbMin
	
	Wscript.Echo "Finalizado el script."

	Set fso = Nothing